gusucode.com > 耐品图片管理系统 标准版A > 耐品图片管理系统 标准版A/Admin_ImagesModifyOk.asp

    <!--#include file="Admin_ChkPurview1.asp"-->
<%
'===============================================================
' 著作权号：中国国家版权局著作权登记号2004SR07385
' 版权所有：深圳市耐品科技开发有限公司 www.naipin.com
' 联系电话：0755-26611119　81234844　81234845
' 联系手机：13316911914
' 联系邮箱：naipin@naipin.com
'===============================================================

If Netout.GetCookie("Self")="0" Then
	Behind.WriteErrMsg("<br><li>对不起，您没有管理图片的权限！</li>")
	Response.End()
End If

Dim TitleId,ImageId
TitleId = Netout.CheckNumeric(Request.Form("TitleId"))
ImageId = Netout.CheckNumeric(Request.Form("ImageId"))

Dim Rs
Set Rs = Server.CreateObject("adodb.recordset")

If TitleId>0 Then
	Dim ClassId
	Dim SpecialId
	Dim TitleName
	Dim ManuName
	Dim TitleDesc
	Dim GroupInfo
	
	ClassId = Netout.CheckNumeric(Request.Form("ClassId"))
	SpecialId = Netout.CheckNumeric(Request.Form("SpecialId"))
	TitleName = Netout.HtmlEncode(Trim(Request.form("TitleName")),True)
	ManuName = Netout.HTMLEncode(Trim(Request.Form("ManuName")),True)
	TitleDesc = Netout.HtmlCode(Request.Form("TitleDesc"),True)

	if ClassID = 0 then
		Behind.WriteErrMsg("<br><li>请选择一个分类！</li>")
	Else
		Rs.Open "Select ClassId,SpecialId,TitleName,ManuName,TitleUser,ICount,IClick from Nt_Title Where TitleId="&TitleId,Conn,1,1
		GroupInfo = Rs.GetRows()
		Rs.Close
		
		If GroupInfo(2,0)&""<>TitleName Or CCur(GroupInfo(0,0))<>ClassId Or GroupInfo(3,0)&""<>ManuName Then
			Rs.Open "Select * from Nt_Title where TitleName='"&TitleName&"' and TitleUser='"&GroupInfo(4,0)&"' and ManuName='"&ManuName&"' and ClassId="&ClassId,Conn,1,3
			If Rs.Eof or Rs.Bof Then
				Rs.Close
				Rs.Open "Select * from Nt_Title where TitleId="&TitleId,Conn,1,3
				Rs("ClassId") = ClassId
				Rs("TitleName") = TitleName
				Rs("SpecialId") = SpecialId
				Rs("ManuName") = ManuName
				Rs("TitleDesc") = TitleDesc
				Rs("UpdateTime") = Now
				Rs.Update
			Else
				Rs("SpecialId") = SpecialId
				Rs("iCount") = Rs("iCount")+GroupInfo(5,0)
				Rs("iClick") = Rs("iClick")+GroupInfo(6,0)
				Rs("ManuName") = ManuName
				Rs("TitleDesc") = TitleDesc
				Rs("UpdateTime") = Now
				Rs.Update
				With Conn
					.Execute("Update NT_Score Set TitleId="&Rs("TitleID")&" where TitleId="&TitleId)
					.Execute("Update NT_Remark Set TitleId="&Rs("TitleID")&" where TitleId="&TitleId)
					.Execute("Update NT_ImgBook Set TitleId="&Rs("TitleID")&" where TitleId="&TitleId)
					.Execute("Delete from NT_title where TitleId="&TitleId)
				End With
			End If
			Rs.Close
		Else
			Rs.Open "Select * from Nt_Title where TitleId="&TitleId,Conn,1,3
			Rs("SpecialId") = SpecialId
			Rs("TitleDesc") = TitleDesc
			Rs("UpdateTime") = Now
			Rs.Update
			Rs.Close
		End If
		Set Rs = Nothing
	End If
ElseIf ImageId>0 Then
	Dim strImageDesc
	strImageDesc = Netout.HtmlCode(Request.Form("ImageInfo1")&"",True)
	
	Rs.Open "Select * from Nt_ImgBook where ID="&ImageId,Conn,1,3
	Rs("ImageDesc") = strImageDesc
	
	If Not Purchase Is Nothing Then
		Purchase.SaveModify Rs,Purchase.GetModify(Request)
	End If
	
	Rs("UpdateTime") = Now()
	Rs.Update
	Rs.Close
	Set Rs = Nothing
End If
Behind.WriteSuccessMsg "修改成功！",Request.Form("Referer")
Set Netout = Nothing
%>